Make one or more unbound combos on your form.  Let the first column be
invisible and be the primary key ID of the recordsource of your form and
then, on its AfterUpdate event...

=FindRecord()

this code goes behind the form:

'~~~~~~~~~~~~~~~~~~~~
Private Function FindRecord()

   'if nothing is picked in the active control, exit
   If IsNull(Me.ActiveControl) Then Exit Function

   'save current record if changes were made
   If me.dirty then me.dirty = false

   'declare a variable to hold the primary key value to look up
   Dim mRecordID As Long

   'set value to look up by what is selected
   mRecordID = Me.ActiveControl

   'clear the choice to find
   Me.ActiveControl = Null

   'find the first value that matches
   Me.RecordsetClone.FindFirst "IDfield = " & mRecordID

   'if a matching record was found, then move to it
   If Not Me.RecordsetClone.NoMatch Then
      Me.Bookmark = Me.RecordsetClone.Bookmark
   End If

End Function

'~~~~~~~~~~~~~~~~~~~~
where
-IDfield is the Name of the primary key field, which is in the
RecordSource of the form -- I am assuming your primary key is a Long
Integer data type (autonumbers are long integers)
-ProcedureName is the name of the procedure that the code is in so if
there is an error, you can see you can see where it is

If you are searching the recordset on another form, substitute
Me --> forms!formname

If on a subform:
Me --> Me.subform_controlname.form

~~~
btw, you should give you ID field a specific name, like UnitID,
ProductID, PriceID, etc...

Warm Regards,
Crystal
 *
     (:  have an awesome day  :)
  *
MVP Access
Remote Programming and Training
strive4peace2006 at yahoo.com
  *