As the DelivDate column must be of text data type rather than date/time to
cater for the "BackOrd" value in the first row then you can't use a simple
subquery correlated on the dates.  You'll need to handle it in code by
wrapping everything up in a function.  The following should do it:

Function GetOrderQtyCalc(lngPartNr As Long, _
                       intOrderQty As Integer, _
                       strDelivDate As String, _
                       varPendQty As Variant)
                       
   Dim strCriteria As String
   Dim dtmPrecDate As Date
   
   If strDelivDate = "BackOrd" Then
       GetOrderQtyCalc = intOrderQty - varPendQty
   Else
       strCriteria = "PartNr = " & lngPartNr & _
           " And CDate(IIF(IsDate(DelivDate),DelivDate,0)) < #" & _
           Format(CDate(strDelivDate), "mm/dd/yyyy") & "#"
       dtmPrecDate = DMax("CDate(IIF(IsDate(DelivDate),DelivDate,0))", _
           "YourOrderTable", strCriteria)
       If dtmPrecDate = 0 Then
           strCriteria = "PartNr = " & lngPartNr & _
               " And DelivDate = ""BackOrd"""
           GetOrderQtyCalc = intOrderQty + DLookup("OrderQty - PendQty", _
               "YourOrderTable", strCriteria)
       Else
           GetOrderQtyCalc = intOrderQty
       End If
   End If
   
End Function

Pate this into a standard module and call it in a query like so:

SELECT PartNr, OrderQty, DelivDate, PendQty,
GetOrderQtyCalc(PartNr,OrderQty,DelivDate,PendQty)
AS OrderQtyCalc
FROM YourOrderTable
ORDER BY PartNr,IIf(IsDate(DelivDate),DelivDate,0);

The above does assume that the PendQty form the first row per PartNr is only
carried forward one row, so even if it resulted in a negative OrderQtyCalc in
that row it would not be carried forward to a subsequent row.

Ken Sheridan
Stafford, England