Formatting names is almost as much of a pain as formatting addresses.
Here is a simple function that will capitalize the first character of each
part of a hyphenated last name.

Public Function HyphenatedName(strLastName As Variant) As Variant

   Dim intCharPos As Integer
   
   If IsNull(strLastName) Then
       HyphenatedName = Null
       Exit Function
   End If
   
   intCharPos = InStr(strLastName, "-")
   Mid(strLastName, 1, 1) = UCase(Mid(strLastName, 1, 1))
   If intCharPos = 0 Then
       HyphenatedName = strLastName
   Else
       Mid(strLastName, intCharPos + 1, 1) = UCase(Mid(strLastName,
intCharPos + 1, 1))
       HyphenatedName = strLastName
   End If
   
End Function

HTH
Dale

Here is a function I wrote long ago that may help you.  The function was
designed to force sentence case in paragraphs but it should

You would call it in query as follows (Note the space after the - in the
argument.  That is needed to force capitals after the space as well as after
the dash.
You could also include other characters such as periods, underscores, etc.

SentenceCaseForTextBlock([FieldName],"- ")

Public Function SentenceCaseForTextBlock(strChange As String, _
           Optional strCapsAfter As String = ".!?", _
           Optional tfForceLowerCase As Boolean = True) As String
'===============================================================================
' Procedure   : SentenceCaseForTextBlock
' Author      : John Spencer
' Purpose     : Applies sentence case to a text block
' Arguments   : strchange is a string.  Handles up to 32K characters.
'               strCapsAfter determines when next letter should be capital
'               tfForceLowerCase if true forces all letters to lowercase
except
'               those capitalized by the strCapsAfter rule
'===============================================================================
Dim LoopCount As Integer  '32K characters
'Dim LoopCount as Long   (change to Long to handle more chars)
Dim tfChange As Boolean
Dim strAscii As Integer

  If tfForceLowerCase = True Then
     strChange = LCase(strChange)
  End If

  tfChange = True

  For LoopCount = 1 To Len(strChange)

     If tfChange = True Then

        Mid(strChange, LoopCount, 1) = _
           UCase(Mid(strChange, LoopCount, 1))

        strAscii = Asc(Mid(strChange, LoopCount, 1))
        tfChange = strAscii < 65 Or strAscii > 90

     ElseIf InStr(1, strCapsAfter, _
              Mid(strChange, _
              LoopCount, 1), vbTextCompare) > 0 Then
        tfChange = True
     End If

  Next LoopCount
  SentenceCaseForTextBlock = strChange

End Function