Alex:

Firstly I'd advise against storing the elapsed times, either in total or
worked, in the table as these can be derived when needed from the start and
end date/time values.  Storing them in columns in the table would introduce
redundancy and the risk of update anomalies.

To get the actual time worked you could call a VBA function.  The following
is adapted from one of mine for computing elapsed times and should give you
the correct duration in the format hh:nn:ss subject to a few assumptions:

1. That the start and end date/time values can only be on a weekday.
2. That a lunch break of fixed length is taken each day.
3. That lunch breaks are taken on every day, including the first and last.

Public Function WorkTime(dtmStart As Date, _
                       dtmEnd As Date, _
                       dtmTimeIn As Date, _
                       dtmTimeOut As Date, _
                       intLunchMinutes As Integer) As String
                       
   Const HOURSINDAY = 24
   Const MINUTESINDAY = 1440
   
   Dim lngHours As Long
   Dim strMinutesSeconds As String
   Dim strDaysHours As String
   Dim dblDuration As Double
   Dim dtmDay As Date
   
   For dtmDay = DateValue(dtmStart) To DateValue(dtmEnd)
       ' if weekend do nothing
       If Weekday(dtmDay, vbMonday) < 6 Then
           Select Case dtmDay
               Case Is = DateValue(dtmStart) ' first day
                   ' get time from start until end of work day
                   dblDuration = dblDuration + (dtmTimeOut -
TimeValue(dtmStart))
                   ' subtract lunch time
                   dblDuration = dblDuration - (intLunchMinutes /
MINUTESINDAY)
                   ' if first and last day are same day then subtract
                   ' time from time out to end of time worked
                   If dtmDay = DateValue(dtmEnd) Then
                       dblDuration = dblDuration - (dtmTimeOut -
TimeValue(dtmEnd))
                   End If
               Case Is = DateValue(dtmEnd) ' last day
                   ' get time from start of work day until end time
                   dblDuration = dblDuration + (TimeValue(dtmEnd) -
dtmTimeIn)
                   ' if start time after lunch subtract lunch time
                   dblDuration = dblDuration - (intLunchMinutes /
MINUTESINDAY)
               Case Else
                   ' if last day is day after first day do nothing more
                   ' otherwise compute time worked for a full day
                   If DateValue(dtmEnd) - DateValue(dtmStart) > 1 Then
                       dblDuration = dblDuration + (dtmTimeOut - dtmTimeIn
- (intLunchMinutes / MINUTESINDAY))
                   End If
           End Select
       End If
   Next dtmDay
   
   'get number of hours
   lngHours = Int(dblDuration) * HOURSINDAY + _
       Format(dblDuration, "h")
   
   ' get minutes and seconds
   strMinutesSeconds = Format(dblDuration, ":nn:ss")
   
   WorkTime = lngHours & strMinutesSeconds
   
End Function

You'll probably find that some longer lines in the code have been split over
two lines in your newsreader, so you might need to correct this after pasting
the function into a standard module in your database.

Assuming a day from 8:00 AM to 6:00PM with a 60 minute lunch break you'd
call the function in a query like so:

SELECT event, user, startdate, enddate,
WorkTime(startdate, enddate, #08:00#, #18:00#, 60)
AS workedtime
FROM YourTable;

or you could call it in the same way in the ControlSource of a computed
control in a form or report.

Ken Sheridan
Stafford, England