Thanks anyway.  Annoying as I prefer using the ADODB model.  Anyway, I
converted to DAO and it works fine.  I'm thinking something about ADO for
parameter queries might be broke.

Here's the full code in DAO.  This procedure might be interesting to others
as it takes the input from four text boxes as filtering criteria and then
populates a Listview control which I use to present selectable records for
the user.  As opposed to the standard Access of approach of binding all
records to the form and then using form navigation to traverse the records --
which just strikes me as awkward.....Different strokes I guess.
---------------------CODE-----------
Private Sub LoadContacts()
   On Error GoTo ErrorHandler

   ' Defines
   Dim iTotal As Integer
   Dim iItems As Integer
   Dim iSubItems As Integer
   Dim lstItem As ListItem
   Dim lstItemNew As ListItem
   Dim dbs As DAO.Database
   Dim qdf As DAO.QueryDef
   Dim rst As DAO.Recordset

   ' Create data objects
   Set dbs = CurrentDb
   Set qdf = dbs.QueryDefs("qryContacts")

   ' Add parameter values -- make sure not null
   qdf.Parameters("[@LastName]").Value = IIf(Len(txtLastName) > 0,
txtLastName, "*")
   qdf.Parameters("[@FirstName]").Value = IIf(Len(txtFirstName) > 0,
txtFirstName, "*")
   qdf.Parameters("[@City]").Value = IIf(Len(txtCity) > 0, txtCity, "*")
   qdf.Parameters("[@Firm]").Value = IIf(Len(txtFirm) > 0, txtFirm, "*")
   
   ' Get data
   Set rst = qdf.OpenRecordset()
   rst.MoveLast
 
   ' Clear the ListView control.
   lvContacts.ListItems.Clear

   ' Add items and subitems to list control. Set Total Records Counter.
   iTotal = rst.RecordCount
   
    ' Loop through recordset and add Items to the control.
   rst.MoveFirst
   For iItems = 1 To iTotal
       If IsNumeric(rst(0).Value) Then
           Set lstItemNew = lvContacts.ListItems.Add(, , Str(rst(0).Value))
       Else
           Set lstItemNew = lvContacts.ListItems.Add(, , rst(0).Value)
       End If
       
       For iSubItems = 1 To rst.Fields.Count - 1
           lstItemNew.SubItems(iSubItems) = rst(iSubItems).Value
       Next iSubItems
       ' Advance to the next record
       rst.MoveNext
   Next iItems
   
   ' Clean up
   qdf.Close
   Set rst = Nothing
   Set qdf = Nothing
   Set dbs = Nothing
   Exit Sub
     
ErrorHandler:
   ' Ignore Error 94 which indicates you passed a NULL value.
   If Err = 94 Then
       Resume Next
   Else
   ' Otherwise display the error message.
       MsgBox "Error: " & Err.Number & Chr(13) & Chr(10) & Err.Description
   End If
End Sub
------------------------------------------------