On Oct 17, 2:02 pm, PiB311 <billga...@discussions.microsoft.com>
wrote:

use this:
http://www.datastrat.com/Code/GetBusinessDay.txt

Public Function AddWorkDays(OriginalDate As Date, DaysToAdd As Integer) As Date
'D Hargis
'OriginalDate = First Day to calculate number of working days from
'DaysToAdd = Number of Working Days to add to OriginalDate
'Returns the date that is the last working day for the number of days
'To look back, pass a negative number of days
'If 0 is entered, the current date is returned

Dim intDayCount As Integer
Dim dtmReturnDate As Date
Dim intAdd As Integer
'Determine whether to add or subtract
   Select Case DaysToAdd
       Case Is >= 1
           intAdd = 1
       Case Is = 0
           AddWorkDays = OriginalDate
           Exit Function
       Case Else
           intAdd = -1
   End Select
       
   intDayCount = 0
   Do While True
       If Weekday(OriginalDate, vbMonday) <= 5 Then    'It is a weekday
           If IsNull(DLookup("[HolDate]", "Holidays", _
               "[HolDate] = #" & OriginalDate & "#")) Then
               intDayCount = intDayCount + intAdd
               dtmReturnDate = OriginalDate
           End If
       End If
       If intDayCount = DaysToAdd Then
           Exit Do
       End If
       OriginalDate = DateAdd("d", intAdd, OriginalDate)
   Loop
   AddWorkDays = dtmReturnDate
End Function