Sorry, missed that in your post. One possibility is a name ambiguity: if you
have a textbox FundNo bound to a field FundNo, then the expression Me!FundNo
is ambiguous. I'm not sure which Access will look at!

Try setting a breakpoint in the code and updating the record. What is the
value of Me.FundNo?

Just fwiw, here's how I'd write the code (which is not to say it's the only
way to write the code, yours very well may work):

Private Sub Form_BeforeUpdate(Cancel as Integer)
Dim rs As DAO.Recordset
Set rs = Me.RecordsetClone
rs.FindFirst "[FundNo] = " & Me![FundNo]
If rs.NoMatch Then
   ' Do nothing
Else
   MsgBox "Fund of this number already exists    ", vbOKOnly +
vbExclamation, "Enter different fund number . . ."
   Cancel = True
   Me!FundNo.Undo ' erase the input
   Me!FundNo.SetFocus
End If
Set rs = Nothing
End Sub

Note that if the Form is filtered, or is based on a query returning a subset
of the funds, you won't find the fund unless it passes the filter; you would
need instead:

Private Sub Form_BeforeUpdate(Cancel as Integer)
Dim db As DAO.Database
Dim rs As DAO.Recordset
Set db = CurrentDb
Set rs = db.OpenRecordset("YourTableName", dbOpenSnapshot)
rs.FindFirst "[FundNo] = " & Me![FundNo]
If rs.NoMatch Then
   ' Do nothing
Else
   MsgBox "Fund of this number already exists    ", vbOKOnly +
vbExclamation, "Enter different fund number . . ."
   Cancel = True
   Me!FundNo.Undo ' erase the input
   Me!FundNo.SetFocus
End If
rs.Close
Set rs = Nothing
End Sub

            John W. Vinson [MVP]