Hi Sue,

I have been reviewing what you have written and need to know more about
your data structure.  Here is something you can do to document that for us:

create a new general module*

paste in this code:

'~~~~~~~~~~~~~~~~~~
'NEEDS REFERENCE to Microsoft DAO library
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'TO DOCUMENT -->
'--- click your mouse into the appropriate Sub below
'--- press F5 to run

Sub RunShowFieldsForTable()
   'edit this line for the tablename you wish to document
   ShowFields "Your tablename"
End Sub

Sub RunShowFieldsForAllTables()
   Dim i As Integer _
      , mTablename As String
   For i = 0 To CurrentDb.TableDefs.Count - 1
      mTablename = CurrentDb.TableDefs(i).Name
      If Left(mTablename, 4) <> "Msys" Then
        Debug.Print 'blank line
        ShowFields mTablename
      End If
   Next i
End Sub
'~~~~~~~~~~~~~~~~~~
Sub ShowFields(pstrTable As String)
    'by DuaneHookom
    'modified by Crystal

    Dim fld As DAO.Field
    Dim tbl As DAO.TableDef
    Dim db As DAO.Database

    Set db = CurrentDb
    Set tbl = db.TableDefs(pstrTable)

    Debug.Print tbl.Name
    Debug.Print "=========================="

    For Each fld In tbl.Fields
      'modified by Crystal
        Debug.Print fld.OrdinalPosition & "  " & fld.Name _
         & ", " & fld.Type & " (" & GetDataType(fld.Type) & ")" _
         & ", " & fld.Size
    Next

    'release object variables
    set fld = nothing
    set tbl = nothing
    set db = nothing

End Sub
'~~~~~~~~~~~~~~~~~~
Function GetDataType(pDatType) As String
   'by Crystal
   Select Case pDatType
      Case 1: GetDataType = "Boolean"
      Case 2: GetDataType = "Byte"
      Case 3: GetDataType = "Integer"
      Case 4: GetDataType = "Long"
      Case 5: GetDataType = "Currency"
      Case 6: GetDataType = "Single"
      Case 7: GetDataType = "Double"
      Case 8: GetDataType = "Date"
      Case 10: GetDataType = "Text"
      Case 12: GetDataType = "Memo"
      Case Else: GetDataType = Format(Nz(pDatType), "0")
   End Select
End Function
'~~~~~~~~~~~~~~~~~~~~~~~~~

then
Debug, compile

click in the RunShowFieldsForAllTables sub
press the F5 key to run

then press CTRL-G to show the debug window

copy the results and paste into a Reply to this thread

'~~~~~~~~~~~~~~~~~~

*How to Create a General Module

1. from the database window, click on the Module tab
2. click on the NEW command button
3. type (or paste) the code in

once the code is in the module sheet, do
Debug,Compile from the menu

if there are no syntax/reference errors, nothing will appear to happen
-- this is good ;)

'~~~~~~~~~~~~~~~~~~

I am a little confused why you are copying data that is already stored
to another record, it sounds like your tables need to be structured
differently.

why not a main table with SpecID and the other relevant information
including a start and stop date?  Why do you feel you need to make a
record for each day and duplicate what is already in the first record?

If you do want to have a daily record, it should be kept in another
table and linked to the main table using an ID field (is SpecID unique
to the first table?).  Then, information in that table would be specific
to that day, not a repeat of anything else already stored.

to help you understand how to structure data in Access, send me an email
and request my 30-page Word document on Access Basics (for Programming)
-- it doesn't cover VBA, but prepares you for it because it covers
essentials in Access.  Be sure to put "Access Basics" in the subject
line so that I see your message...

Warm Regards,
Crystal
 *
     (:  have an awesome day  :)
  *
MVP Access
Remote Programming and Training
strive4peace2006 at yahoo.com
  *