You should realize you're asking a lot.  These newsgroups aren't really
intended as a place to get people to write your code for you, though
demonstrative code snippets are standard fare.

Well, since I'm such a softy ... here's a version that may or may not
work the way you want, but would be a place to start:

'----- start of code -----
Function FixMovieTimes()

   Dim db As DAO.Database
   Dim rst As DAO.Recordset
   Dim rsAdd As DAO.Recordset

   Dim lngEndTime As Long
   Dim lngGap As Long

   Dim ClSgn_Prev As Variant
   Dim LogDt_Prev As Variant
   Dim EndTm_Prev As Variant

   Set db = CurrentDb

   ' Open a recordset on the existing records, sorted by start time.
   Set rst = db.OpenRecordset( _
           "SELECT * FROM tblMovie ORDER BY [Strt tm]")
   ' Open a separate, empty recordset to add records.
   Set rsAdd = db.OpenRecordset( _
           "SELECT * FROM tblMovie WHERE False")

   With rst

       If Not .EOF Then
           ' Set initial "previous" values.
           EndTm_Prev = "000000"
           ClSgn_Prev = ![Cl Sgn]
           LogDt_Prev = ![Log Dt]
       End If

       Do Until .EOF

           ' Do we have a gap between this record and the previous one?
           lngGap = CLng(![Strt tm]) - CLng(EndTm_Prev)
           If lngGap > 0 Then
               ' Create a record to fill that gap.
               With rsAdd
                   .AddNew
                       ![PTyp] = "PGR"
                       ![Log Dt] = LogDt_Prev
                       ![Cl Sgn] = ClSgn_Prev
                       ![Strt tm] = EndTm_Prev
                       ![End tm] = rst![Strt tm]
                       ![Dur] = Format(lngGap, "000000")
                   .Update
               End With
           End If

           ' Compute end time for current record
           If ![PTyp] = "PGR" Then
               .MoveNext
               If .EOF Then
                   lngEndTime = -1
               Else
                   lngEndTime = CLng(![Strt tm])
               End If
               .MovePrevious
           Else

               lngEndTime = CLng(![Strt tm]) + CLng(!Dur)
           End If

           ' Update the record.
           .Edit
           If lngEndTime < 0 Then
               ' Don't know when this movie ends!
               ![End tm] = Null
           Else
               ![End tm] = Format(lngEndTime, "000000")
           End If
           .Update

           ' Save this record's values as "previous" for the
           ' next record.
           EndTm_Prev = ![End tm]
           ClSgn_Prev = ![Cl Sgn]
           LogDt_Prev = ![Log Dt]

           ' Go on to the next movie.
           .MoveNext

       Loop

       ' All done.  Close the recordset.
       .Close

   End With

   rsAdd.Close
   Set rst = Nothing
   Set rsAdd = Nothing
   Set db = Nothing

End Function

'----- end of code -----

I notice that you have these two records in your sample, which seem to
conflict:

And there are some other overlaps, as well.  I don't know what you would
want to do in these cases.