Hi Keith

Have you considered using the 'Microsoft Office Outlook View Control'
ActiveX control - get it from 'More Controls' on the Access Tools toolbar.
This provides a window through to the Outlook Calender items from where you
can Delete any item.

Cheers.

BW

To BW:    I've not seen the Microsoft Office Outlook View Control before.
How do you get it to display the Calendar? I could only get it to display
the Inbox

To Keith:  You asked for help with automation. As you don't say what
information you store in Access to keep track of Calendar items, I give
three demonstrations below, which you can copy and paste into an Access
module and modify to suit you best:

Demo 1 - How to delete an Appointment Item if you know its subject.

Demo 2 - How to delete an Appointment Item if you know its start date/time.

Demo 3 - How to permanently delete an Appointment Item if you know its start
date/time.

Demos 1 and 2 will move the deleted item to the Deleted Items folder.
Demo 3 won't.

You will have to modify these demos so as to uniquely identify the
Appointment Item you want to delete.  For example, you could check the
appointment's start date/time *and* its subject heading. You could
additionally test for any other properties you have values for before you
invoke the delete method.

I recommend you backup your Outlook data file *before* running a program
that automatically deletes anything. Then get the program to delete one item
to begin with and verify the program works as you expect.

Outlook stores its data in files with the filename extension *.pst. These
used to be known as personal store files. You can open the File menu and
select Data File Management to find out where these files are on your hard
disc.

Geoff

Option Compare Database
Option Explicit

'------------------------------------------------------
'   This Access module needs references to:
'
'   Microsoft Outlook [VersionNo] Object Library
'   Microsoft CDO 1.21 Library
'
'   To set references, in the VBA Editor, open the
'   Tools menu and select References.
'------------------------------------------------------

'   OUTLOOK OBJECT VARIABLES:

Private mobjOLA As Outlook.Application
Private mobjNS As Outlook.NameSpace
Private mobjFLDR As Outlook.MAPIFolder
Private mobjAPPT As Outlook.AppointmentItem

'   CDO (COLLABORATION DATA OBJECTS) VARIABLES:

Private mobjCDOSession As MAPI.Session
Private mobjMAPIAppt As MAPI.Message

Private Sub ExampleCall_DeleteBySubject()

   '   Read note below!

   Dim strSubject As String

   '   Delete an appointment with the subject heading
   '   "My Test Appointment":
   strSubject = "My Test Appointment"
   Call DeleteAppointmentItemBySubject(strSubject)

End Sub

Private Sub DeleteAppointmentItemBySubject(strSubject As String)

   '   Use this method ONLY if the subject of the
   '   Appointment Item is known and is UNIQUE.

   Set mobjOLA = CreateObject("Outlook.Application")
   Set mobjNS = mobjOLA.GetNamespace("MAPI")
   mobjNS.Logon , , False, False
   Set mobjFLDR = mobjNS.GetDefaultFolder(olFolderCalendar)

   On Error Resume Next
   Set mobjAPPT = mobjFLDR.Items(strSubject)
   If Err.Number <> 0 Then GoTo CannotFindObject
   mobjAPPT.Delete

Bye:

   Set mobjAPPT = Nothing
   Set mobjFLDR = Nothing
   Set mobjNS = Nothing
   Set mobjOLA = Nothing

   Exit Sub

CannotFindObject:

   MsgBox "Cannot find Appointment Item to delete.", _
       vbOKOnly, "Information"
   GoTo Bye

End Sub

Private Sub ExampleCall_NotPermanentDelete()

   '   Read note below!

   Dim datApptStart As Date
   Dim datDate As Date
   Dim datTime As Date

   '   Delete (not permanently) an appointment that
   '   starts on March 1, 2007, at 9 am:
   datDate = DateSerial(2007, 3, 1)
   datTime = TimeSerial(9, 0, 0)
   datApptStart = datDate + datTime
   Call DeleteToDeletedFolder(datApptStart)

End Sub

Private Sub DeleteToDeletedFolder(datStart As Date)

   '   Use this subprocedure if you have the start date and time
   '   of the Appointment you want to delete.

   '   This subprocedure can be modified to test for any known
   '   property or properties of the appointment item.  As more
   '   than one appointment could start at the same time, it
   '   would be necessary to examine another property to
   '   determine which one should be deleted. Modify the "If"
   '   statement accordingly.

   '   This subprocedure will place the deleted item in the
   '   Deleted Items folder.

   '   This subprocedure may be unsuitable if there are a
   '   large number of items in the Calendar folder (see
   '   using CDO below).

   Dim fItemDeleted As Boolean

   fItemDeleted = False
   Set mobjOLA = CreateObject("Outlook.Application")
   Set mobjNS = mobjOLA.GetNamespace("MAPI")
   mobjNS.Logon , , False, False
   Set mobjFLDR = mobjNS.GetDefaultFolder(olFolderCalendar)

   For Each mobjAPPT In mobjFLDR.Items
       If mobjAPPT.Start = datStart Then
           mobjAPPT.Delete
           fItemDeleted = True
           Exit For
       End If
   Next

   If fItemDeleted = False Then
       MsgBox "Cannot find Appointment Item to delete.", _
           vbOKOnly + vbExclamation, "Information"
   End If

   Set mobjAPPT = Nothing
   Set mobjFLDR = Nothing
   Set mobjNS = Nothing
   Set mobjOLA = Nothing

End Sub

Private Sub ExampleCall_DeletePermanently()

   '   Read note below!

   Dim datApptStart As Date
   Dim datDate As Date
   Dim datTime As Date

   '   Delete (permanently) an appointment that
   '   starts on March 1, 2007, at 10:30 am:
   datDate = DateSerial(2007, 3, 1)
   datTime = TimeSerial(10, 30, 0)
   datApptStart = datDate + datTime
   Call PermanentlyDeleteAppointment(datApptStart)

End Sub

Private Sub PermanentlyDeleteAppointment(datStart As Date)

   '   This subprocedure needs a reference to the
   '   Microsoft CDO 1.21 Library.

   '   CDO is much faster and more reliable if looping
   '   through a large collection of items.

   '   This subprocedure will delete an appointment
   '   item and will *NOT* place it in the Deleted Items
   '   folder.

   '   This subprocedure can be modified to test for any known
   '   property or properties of the appointment item.  As more
   '   than one appointment could start at the same time, it
   '   would be necessary to examine another property to
   '   determine which one should be deleted. Modify the "If"
   '   statement accordingly.

   Dim fItemFound As Boolean
   Dim strEntryID As String
   Dim strStoreID As String

   fItemFound = False
   Set mobjOLA = CreateObject("Outlook.Application")
   Set mobjNS = mobjOLA.GetNamespace("MAPI")
   mobjNS.Logon , , False, False
   Set mobjFLDR = mobjNS.GetDefaultFolder(olFolderCalendar)

   '   Loop through Calendar folder until the item with
   '   the incoming datStart is found:
   For Each mobjAPPT In mobjFLDR.Items
       If mobjAPPT.Start = datStart Then
           fItemFound = True
           Exit For
       End If
   Next

   If fItemFound Then
       GoTo DeleteAppointmentItemUsingCDO
   Else
       GoTo AppointmentItemNotFound
   End If

Bye:

   Set mobjAPPT = Nothing
   Set mobjFLDR = Nothing
   Set mobjNS = Nothing
   Set mobjOLA = Nothing

   Exit Sub

DeleteAppointmentItemUsingCDO:

   '   Get EntryID from Outlook Appointment item:
   strEntryID = mobjAPPT.EntryID

   '   Get Folder's storeID:
   strStoreID = mobjFLDR.StoreID

   '   Logon to CDO:
   Call DoCDOLogon

   '   Point MAPI object to Appointment Item:
   Set mobjMAPIAppt = mobjCDOSession.GetMessage(strEntryID, _
       strStoreID)

   '   Delete MAPI object:
   mobjMAPIAppt.Delete

   '   Logoff from CDO (see note under DoCDOLogon):
   Call DoCDOLogoff

   GoTo Bye

AppointmentItemNotFound:

   MsgBox "Cannot find Appointment Item to delete.", _
       vbOKOnly + vbExclamation, "Information"

   GoTo Bye

End Sub

Private Sub DoCDOLogon()

   '   If deleting many items, do not logon and logoff
   '   repeatedly to CDO in quick succession. Instead,
   '   modify the code to logon once at the beginning
   '   of a delete session and logoff at the end of
   '   the session.

   If mobjCDOSession Is Nothing Then
       Set mobjCDOSession = CreateObject("MAPI.Session")
       mobjCDOSession.Logon , , False, False
   End If

End Sub

Private Sub DoCDOLogoff()

   '   See note under DoCDOLogon.

   If mobjCDOSession Is Nothing Then Exit Sub
   mobjCDOSession.Logoff
   Set mobjCDOSession = Nothing

End Sub