Here is a function that will accept a query or table name and return a
string of HTML. You can specify whether you want headings or not. I suppose
you could pass in a file name if you wanted the HTML to go directly into a
file.

Function TableQueryToHTML(strQueryName As String, _
           Optional booHeadings As Boolean = -1) As String
   Dim rs As DAO.Recordset
   Dim db As DAO.Database
   Dim fld As DAO.Field
   Dim strHTML As String
   Set db = CurrentDb
   Set rs = db.OpenRecordset("Select * from [" & strQueryName & "]")
   strHTML = "<Table>" & Chr(13) & Chr(10)
   If booHeadings = True Then
       strHTML = strHTML & "  <tr>" & Chr(13) & Chr(10)
           For Each fld In rs.Fields
               strHTML = strHTML & "    <th>" & _
                   fld.Name & "</th>" & Chr(13) & Chr(10)
           Next
       strHTML = strHTML & "  </tr>" & Chr(13) & Chr(10)
   End If

   With rs
       Do Until .EOF
           strHTML = strHTML & "  <tr>" & Chr(13) & Chr(10)
           For Each fld In .Fields
               strHTML = strHTML & "    <td>" & _
                   fld.Value & "</td>" & Chr(13) & Chr(10)
           Next
           strHTML = strHTML & "  </tr>" & Chr(13) & Chr(10)
           .MoveNext
       Loop
       .Close
   End With
   Set rs = Nothing
   Set db = Nothing
   strHTML = strHTML & "</Table>"
   TableQueryToHTML = strHTML
End Function