Here's a function you can paste into a standard module and use in place
of the builtin Split() function for cases like this:

'----- start of code -----
Function SplitWords( _
           ByVal pstrSource As String, _
           Optional pstrDelim As String = " ", _
           Optional plngLimit As Long = -1, _
           Optional pCompare As Long = vbBinaryCompare) _
       As String()

   ' Split the argument pstrSource into an array of "words"
   ' based on the delimiter passed as pstrDelim, treating
   ' consecutive occurrences of the delimiter as a single
   ' occurrence.  So, for example, SplitWords("This   Function")
   ' returns the same output array as SplitWords("This Function").
   '
   ' Written by: Dirk Goldgar
   '             on: 8 March, 2005

   Dim strTwoDelim As String
   Dim lngLen As Long

   strTwoDelim = pstrDelim & pstrDelim

   Do
       lngLen = Len(pstrSource)
       pstrSource = Replace(pstrSource, strTwoDelim, pstrDelim, 1, -1,
pCompare)
   Loop Until Len(pstrSource) = lngLen

   SplitWords = Split(pstrSource, pstrDelim, plngLimit, pCompare)

End Function
'----- end of code -----

I just threw it together, but it seems to work.