i'd prob use excel for making a grid page

http://members.ozemail.com.au/~ae42/Book1.xls

open that and save as a xls on your puter then open it with excel it's
actually really easy to make

If you are referring to a grid on a report, you can either use line or
rectangle controls or the Line method. The following code uses the Line
method to draw the current month's calendar page.

Private Sub Report_Page()
   Dim lngDayHeight As Long
   Dim lngDayWidth As Long
   Dim datRptDate As Date
   Dim intStartWeek As Integer
   Dim lngTopMargin As Long
   Dim dat1stMth As Date
   Dim datDay As Date
   Dim lngTop As Long
   Dim lngLeft As Long
   datRptDate = Date
   dat1stMth = DateSerial(Year(datRptDate), Month(datRptDate), 1)
   intStartWeek = DatePart("ww", dat1stMth)
   lngDayHeight = 2160  'one & half inch
   lngDayWidth = 1440  'one inch
   lngTopMargin = 720  'half inch
   Me.FontSize = 22
   'loop through all days in month
   For datDay = dat1stMth To DateAdd("m", 1, dat1stMth) - 1
       'find the top and left corner
       lngTop = (DatePart("ww", datDay) - intStartWeek) * _
           lngDayHeight + lngTopMargin
       lngLeft = (Weekday(datDay) - 1) * lngDayWidth
       If Weekday(datDay) = 1 Or Weekday(datDay) = 7 Then
           Me.DrawWidth = 8
        Else
           Me.DrawWidth = 1
       End If
       'draw a rectangle for day
       Me.Line (lngLeft, lngTop)-Step _
               (lngDayWidth, lngDayHeight), , B
       Me.CurrentX = lngLeft + 50
       Me.CurrentY = lngTop + 50
       Me.Print Day(datDay)
   Next
End Sub