Hi John,

It should be
    Like "[A-Za-z]"
not
    Like "[aA-zZ]
but you may also need to specify numerals and accented characters, e.g.
    Like "[0-9A-Za-záâçèéêëôûÇ]"

However, you can also specify a "negative" character class, e.g.
    Like "[!a-z]"
where the ! is a signal to match all characters that are _not_ listed.

So you could use something like
    Like "[!.,:;!?_-!/\]"
to exclude punctuation marks. (There's the slight problem that the Like
operator won't let you use ] in a character class because it's needed to
signal the end of a class.

Here's a slightly neater function that will strip out all the characters
except those you specify. Note the way I've declared the variables and
given all the variables and arguments meaningful names, which makes the
code a great deal easier to understand than with names like var111 and
var114.

Function StripChars(V As Variant, CharsToKeep As String) As Variant
 'CharsToKeep must be a character class for the
 '  Like operator, e.g. [A-Za-z]
   
 Dim C As String * 1
 Dim strIn As String
 Dim strOut As String
 Dim j As Long
 
 If IsNull(V) Then
   StripChars = Null
   Exit Function
 End If
 
 strIn = CStr(V)
 
 For j = 1 To Len(strIn)
   C = Mid(strIn, j, 1)
   If C Like CharsToKeep Then
     strOut = strOut & C
   Else
     strOut = strOut & " "
   End If
 Next
 StripChars = strOut
End Function

--
John Nurick [Microsoft Access MVP]

Please respond in the newgroup and not by email.