Hi Dan

Try using this function:

Public Function CountCampDays( _
   dtStart As Date, _
   dtEnd As Date) _
   As Integer
Const cDateFormat = "\#mm\/dd\/yyyy\#"
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim iCount As Integer
Dim dtNext As Date
On Error GoTo ProcErr
 Set db = CurrentDb
 Set rs = db.OpenRecordset("Select HoliDate From Holidays " _
   & "where HoliDate between " & Format(dtStart, cDateFormat) _
   & " and " & Format(dtEnd, cDateFormat))
 For dtNext = dtStart To dtEnd
   If Weekday(dtNext, vbMonday) < 5 Then
     rs.FindFirst "HoliDate=" & Format(dtNext, cDateFormat)
     If rs.NoMatch Then iCount = iCount + 1
   End If
 Next
 CountCampDays = iCount
ProcEnd:
 On Error Resume Next
 rs.Close
 Set rs = Nothing
 Set db = Nothing
 Exit Function
ProcErr:
 MsgBox Err.Description
 Resume ProcEnd
End Function

Some tricks to note:

1. Weekday(dtNext, vbMonday) starts counting the weekday from Monday, so you
just need to check for <5 instead of =6 or =7 or =1

2. Opening a recordset of holidays between the two dates is much more
efficient than doing a whole series of DLookups.

3. Whenever you compare dates in SQL (including FindFirst and DLookup etc)
you must use the American dat e format (mm/dd/yyyy).  Your code is using
dd/mm/yyyy and will not work.