The following would all go into your form module. Add error handling, adjust
control/field names, etc., as appropriate for your reality.

'***** start aircode **********
Option Explicit
'(Top-of-form module) Module-level variables:
Private mstrRecordFilter as String
Private mstrEmpFilter as String

Private Sub frmOption1_AfterUpdate()
   Select Case Me.frmOption1
       Case 1
           'All records
           mstrRecordFilter = ""
       Case 2
           mstrRecordFilter = "[Active] = True"
       Case 3
           mstrRecordFilter = "[Active] = False"
   End Select
   Call ApplyFormFilter
End Sub

Private Sub frmOption2_AfterUpdate()
   Select Case Me.frmOption2
       Case 1
           mstrEmpFilter = "[EmpType] = 'Company'"
       Case 2
           mstrEmpFilter = "[EmpType] = 'Temp'"
       Case 3
           ' All employees
           mstrEmpFilter = ""
   End Select
   Call ApplyFormFilter
End Sub

Private Sub ApplyFormFilter()
       Dim strCombinedFilter as String

       ' Combine the 2 filters
       Select Case True
           ' Only one of these 3 things will execute: the 1st True
condition encountered
           Case mstrRecordFilter = ""
               strCombinedFilter = mstrEmpFilter
           Case mstrEmpFilter = ""
               strCombinedFilter = mstrRecordFilter
           Case Else
               ' User wants to filter on multiple fields
               strCombinedFilter = mstrRecordFilter & " AND " &
mstrEmpFilter
       End Select

       'Apply the combined filter
       Me.Filter = strCombinedFilter
       If strCombinedFilter = "" Then
           Me.FilterOn = False
       Else
           Me.FilterOn = True
       End If
End Sub
'******* end aircode **************************