Unless your user has 100's of Mbytes of data, you (and the user) are better
off NOT putting some data in db1, some in db2, some in db3, ... and then
trying to connect them all together.

Instead, include either a Yes/No field (you could call it, say, "Archived")
in the table(?s?) that hold the data being considered.  Then modify the
everyday queries to exclude data that has Archived = Yes.  You can still
create a query to look at any of the historical data.

Or include a date/time field that holds the date/time when the record was
archived, and modify your queries to exclude any before, say, 1/1/2007 (or
any other time period).

Regards

Jeff Boyce
Microsoft Office/Access MVP

Try running code like this:

Public Function ChangeLinks(strNewPath As String) As Boolean
'************************************************************
' Name: ChangeLinks
' Purpose:
'
' Inputs: strNewPath As String
'
' Returns: Boolean
'
' Author: Arvin Meyer
' Date: September 5, 1998
' Comment: Change the Link to a different back-end database
'
'*************************************************************
On Error GoTo Err_ChangeLinks

Dim db As DAO.Database
Dim i As Integer

Set db = CurrentDb

   For i = 0 To db.TableDefs.Count - 1
       If Len(db.TableDefs(i).Connect) > 0 Then
           db.TableDefs(i).Connect = ";DATABASE=" & strNewPath
           db.TableDefs(i).RefreshLink
       End If
   Next i

   db.TableDefs.Refresh
   ChangeLinks = True

Exit_ChangeLinks:
Set db = Nothing
Exit Function

Err_ChangeLinks:
ChangeLinks = False

Select Case Err

Case 0

Case 3044
 Resume Next

Case Else
 MsgBox Err.Number & ": " & Err.Description
 Resume Exit_ChangeLinks
End Select

End Function