Hi Paul,

OK, here are the assumptions I used:

The first thru the xx fields are type integer
The names of the fields begin with "F" and are numbered sequentially.
If there are 10 integer fields, they must be numbered 1-10. (can not skip 9
and use 11)

The fields do not have to be in order ie F1, F2, F3,... (F1,F20, F2, F4,
..., is OK) but there cannot be a non-integer field between the integer
fields (can not be F1, F2, Status, F3 ,...)

The field that holds "Valid" or "Spoiled" is a text field.

The function should be put in a standard module. The module name cannot be
the same as the function.

I create a new form, in continous forms with all of the field in the form
(record source is a query). Then I added a button to call the function.
To call the function I created a button and used the Click event with the
following code:

'---
   Dim temp As Variant

   'saves any changes to data if on a form
   If Me.Dirty Then
       Me.Dirty = False
   End If

   'temp is a throw away value
   temp = IsValidVote("Voting", 3)
                                ^^^^^
                       'table name goes here

  'if on a form
   Me.Refresh
'---

Chagne the table name to your table. You might want to use a text box on a
form to enter the table name.

Here is the function. I named it "IsValidVote"

'----beg code-----------
Public Function IsValidVote(pstrTableName As String, Optional pintMaxVotes
As Integer)
   On Error GoTo IsValidVoteErr

   Dim db As DAO.Database
   Dim tdf As DAO.TableDef
   Dim fld As DAO.Field
   Dim rst As DAO.Recordset

   Dim strSQL As String

   Dim i As Integer
   Dim vNumColumns As Integer
   Dim vNumVotes As Integer

   If IsNull(pintMaxVotes) Then
       pintMaxVotes = 3
   End If

   Set db = CurrentDb()
   Set tdf = db.TableDefs(pstrTableName)

   vNumColumns = 0

   For Each fld In tdf.Fields
       ' field type 3 = Integer
       If fld.Type = 3 Then
           strSQL = strSQL & fld.Name & ", "
           vNumColumns = vNumColumns + 1
       End If
   Next

   ' create SQL string
   If Len(strSQL) > 0 Then
       strSQL = "Select " & strSQL & "Status FROM " & pstrTableName
   End If

   'open recordset
   Set rst = db.OpenRecordset(strSQL)

   With rst
       If Not (rst.BOF And rst.EOF) Then
           .MoveFirst
           Do While Not rst.EOF
               vNumVotes = 0
               'count number of non null columns
               For i = 1 To vNumColumns
               'field names MUST begin with 'F'
                   If .Fields("F" & i) > 0 Then
                       vNumVotes = vNumVotes + 1
                   End If
               Next
               'update the Status column
               .Edit
               If vNumVotes <= pintMaxVotes Then
                   .Fields("Status") = "Valid"
               Else
                   .Fields("Status") = "Spoiled"
               End If
               .Update
               .MoveNext
           Loop
       Else
           MsgBox "No records found in table " & pstrTableName
       End If
   End With

   If Not rst Is Nothing Then
       rst.Close
       Set rst = Nothing
   End If

IsValidVoteExit:

   Set db = Nothing
   Exit Function

IsValidVoteErr:

   Select Case Err
   Case 3265&  'Table name invalid
       If Err.Source = "DAO.Fields" Then
           MsgBox "Invalid field name"
       ElseIf Err.Source = "DAO.TableDefs" Then
           MsgBox pstrTableName & " table doesn't exist"
       End If
   Case Else
       Debug.Print "TableInfo() Error " & Err & ": " & Error
   End Select
   Resume IsValidVoteExit

End Function

'------end code ------

HTH