Make sure you don't have any open connections to the backend (no open bound
forms, that sort of thing).

What I typically do is run a little routine that renames the backend to a
backup file, then compact the renamed file to the name of the original
backend file. Apologies if there's word-wrap in what's below

Function CompactDatabase( _
  DatabaseName As String) As Boolean
' Renames the existing backend database
' from .MDB to .BAK
' Compacts the backup copy to the
' "proper" database
'
' Returns True if successful, False otherwise

On Error GoTo Err_CompactDatabase

Dim booStatus As Boolean
Dim strBackupFile As String

   booStatus = True

' Make sure that DatabaseName exists
   If Len(Dir$(DatabaseName)) > 0 Then

' Figure out what the backup file should be named
       If StrComp(Right$(DatabaseName, 4), _
          ".mdb", vbTextCompare) = 0 Then
           strBackupFile = Left$(DatabaseName, _
               Len(DatabaseName) - 4) & ".bak"

' Determine whether the backup file already exists,
' and delete it if it does.
           If Len(Dir$(strBackupFile)) > 0 Then
               Kill strBackupFile
           End If

           Name DatabaseName As strBackupFile

' Do the actual compact
           DBEngine.CompactDatabase strBackupFile, _
              DatabaseName
       End If

   End If

End_CompactDatabase:
   CompactDatabase = booStatus
   Exit Function

Err_CompactDatabase:
   booStatus = False
   DisplayError Err, "CompactDatabase"
   Resume End_CompactDatabase

End Function